Wikidata #

https://www.wikidata.org/

SPARQLクエリエディタ #

Endpoint: https://query.wikidata.org/sparql

文化・芸術系に関係のあるクラス #

…

「芸術作品」の下位クラスを探す #

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7SELECT
 8  ?entity ?entityLabel
 9WHERE {
10  # "芸術作品" の下位クラス
11  ?entity wdt:P279* wd:Q838948 .
12  FILTER EXISTS { ?s wdt:P31 ?entity . }
13  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
14}
15LIMIT 1000

▶ 実行する

「日本のアニメおよび漫画」の一部分・下位クラスを探す #

Q10901350　(日本のアニメおよび漫画)

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7SELECT
 8  ?entity ?entityLabel
 9WHERE {
10  # "日本のアニメおよび漫画" の下位クラス
11  # "日本のアニメおよび漫画" の一部分であるクラス
12  # "日本のアニメおよび漫画" の一部分であるクラスの下位クラス
13  ?entity wdt:P279*/wdt:P361* wd:Q10901350 .
14  FILTER EXISTS { ?s wdt:P31 ?entity . }
15  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
16}

▶ 実行する

文化・芸術系に関係のあるプロパティ #

メディア芸術データベースとのリンク #

P7886 (メディア芸術データベース識別子)

使用例 #

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7SELECT ?item ?itemLabel ?value
 8{
 9  ?item wdt:P7886 ?value .
10  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en"  }
11}
12LIMIT 1000

▶ 実行する

クラスごとの使用数 #

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7#top 50 for P31 and P279 of items using P7886
 8SELECT ?class ?classLabel ?count ?use_as_Label
 9{  {  SELECT ?class (COUNT(*) AS ?count) (wd:P31 as ?use_as_)
10    {  ?a  wdt:P7886  ?p  ; wdt:P31  ?class}
11        GROUP BY ?class ORDER BY DESC(?count) LIMIT 50
12    }
13    UNION
14  {  SELECT ?class (COUNT(*) AS ?count) (wd:P279 as ?use_as_)
15    {  ?a  wdt:P7886  ?p  ; wdt:P279  ?class}
16        GROUP BY ?class ORDER BY DESC(?count) LIMIT 50
17    }
18    SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en" }
19}
20ORDER BY DESC(?count) ?class

▶ 実行する

クエリ例 #

2020年に公開された邦画 #

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7SELECT DISTINCT ?item ?itemLabel
 8WHERE {
 9  ?item wdt:P31 wd:Q11424 ; # 映画
10        wdt:P495 wd:Q17 ; # 日本
11        wdt:P577 ?pubdate .
12  FILTER((?pubdate >= "2020-01-01T00:00:00Z"^^xsd:dateTime) && (?pubdate <= "2020-12-31T00:00:00Z"^^xsd:dateTime))
13  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
14}

▶ 実行する

wd:Q11424 を wd:Q7889 (コンピュータゲーム) など、別のクラスに変えて試してみる。

映画とその物語の場所を地図上に #

1#defaultView:Map
2SELECT ?movie ?movieLabel ?narrative_location ?narrative_locationLabel ?coordinates
3WHERE {
4   ?movie wdt:P840 ?narrative_location ;
5          wdt:P495 wd:Q17 ; # 日本
6          wdt:P31 wd:Q11424 . # 映画
7   ?narrative_location wdt:P625 ?coordinates .
8  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
9}

Wikidata Query Serviceで実行

Ref. Wikidata:SPARQLクエリサービス/クエリ/例#映画とその物語の場所を地図上により

SFライトノベル #

 1PREFIX bd: <http://www.bigdata.com/rdf#>
 2PREFIX wikibase: <http://wikiba.se/ontology#>
 3PREFIX wd: <http://www.wikidata.org/entity/>
 4PREFIX wdt: <http://www.wikidata.org/prop/direct/>
 5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
 6
 7SELECT DISTINCT ?item ?itemLabel
 8WHERE {
 9  ?item wdt:P31/wdt:P279* wd:Q747381 ; # ライトノベル
10        wdt:P136/wdt:P279* wd:Q9326077 . # スペキュレイティブ・フィクション 
11  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ja,en". }
12}

▶ 実行する